lookjapan.COM - IRC ve mIRC dünyasının forumu!

IP bilgilerini kanala yansıtmak dışında farklı olarak, html kodlarına işleyip pencereye aktarıyor.

Biraz farklı olsun istedim. Profesyonel olmasa da, farklı kodlarda buna benzer fonksiyonlar geliştirilebilir. Bende fırsat buldukça kullanacağım.

Kodun kullanımı:

- Kodda bulunan #kanal kısmına kullanmak istediğiniz #kanal(lar)ı belirtin.

- !knerden <IpAdresi> Komutu kullandığınız aktif kanala bilgileri yansıtır.

-!nerden <IpAdresi> @Nerden isimli pencere açar ve bilgileri o pencereye aktarır. Pencerede bulunan butonlarla pencereyi kapatabilir veya penceredeki bilgileri, komutu kullandığınız kanala yansıtabilirsiniz.

Gerekli dosyalar:

1-) [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] <- Tıklayın (mIRC Klasörüne atınız //run $mircdir)

2-) [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] <- Tıklayın veya en alttaki eklentiden indirin. (mIRC Klasörüne atınız //run $mircdir)

Not: Kodu, /load -rs dosyaadı.txt komutu ile yüklerseniz ve mIRC Klasörünüzde üstte belirttiğim dll dosyası eksik ise, indirme linkini echo mesajı ile yansır.
- Ayrıca mIRC Dll kullanımı kapalı ise, bunu aktifleştirmeniz için mIRC Dll kullanımını aktif hale getirebileciğiniz pencere açılır.

Koddan örnek görüntüler:

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

Kod:

on *:load:{ 

  if ($lock(dll) = $true) && ($isfile(nhtmln_2.95.dll) = $true) { 

    echo 4 -tae mIRC dll kullanımı kapalı, nhtmln_2.95.dll kullanımı için açılan ekranda Dll seçeneğindeki işareti kaldırın ve tekrar yüklemeyi deneyin.

    .comopen dl wscript.shell | .comclose dl $com(dl,sendkeys,1,bstr,% $+ o) 

  }

  elseif ($lock(dll) = $true) && ($isfile(nhtmln_2.95.dll) = $false) { 

    echo 4 -tae mIRC dll kullanımı kapalı, nhtmln_2.95.dll'nin çalışabilmesi için açılan ekranda Dll seçeneğindeki işareti kaldırın.

    .comopen dl wscript.shell | .comclose dl $com(dl,sendkeys,1,bstr,% $+ o) 

    echo 4 -tae mIRC Klasörünüzde (//run $!mircdir) nhtmln_2.95.dll bulunamadı. 

    echo 4 -tae Download: http://www.mircscripts.org/download.php?id=2463&type=5 Adresinden indirip tekrar yükelemeyi deneyin.

  }

  elseif ($lock(dll) = $false) && ($isfile(nhtmln_2.95.dll) = $false) {

    echo 4 -tae mIRC Klasörünüzde (//run $!mircdir) nhtmln_2.95.dll bulunamadı. 

    echo 4 -tae Download: http://www.mircscripts.org/download.php?id=2463&type=5 Adresinden indirip tekrar yüklemeyi deneyin.

  }

  elseif ($lock(dll) = $false) && ($isfile(nhtmln_2.95.dll) = $true) { echo 4 -tae IP Sorulama kodu yüklendi. }

}



alias nerden {

  var %rd $mid($md5($ticks),5,$r(10,20))

  sockopen $+(yerbul,%rd) www.ipaddresslocation.org 80

  sockmark $+(yerbul,%rd) $1- 

}



alias derle { 

  if (%kanal) { return $regsubex($1-,/\x3C.+\x3E/gSU,) }

  else { return $regsubex(i,$regsubex($1-,/\x3C.+\x3E/gSU,),/.+\x3A(.+)/,\1) }

}



alias webb { 

  $iif(!$window(@Nerden), window -Cdk0o +de @Nerden 260 100 500 300) 

  noop $dll(nHTMLn_2.95.dll,attach,$window(@Nerden).hwnd)

  noop $dll(nHTMLn_2.95.dll,navigate,$mircdirip-.html) 

  dll nHTMLn_2.95.dll handler wcntrl 

}



alias wcntrl {

  if ($2 == navigate_begin) && (mirc:* iswm $3) { $($mid($3,6),2) | return S_CANCEL } 

  return S_OK

}



alias wclose { window -c @Nerden }



alias dyansit { 

  var %1 $chr(186)

  %ms -

  %ms -4 %ipd 2IP Adresi Sonuçları -

  %ms %1 5IP Ülke:2 %con

  %ms %1 5IP Ülke Kodu:2 %cnc

  %ms %1 5IP Kıta:2 %cot

  %ms %1 5IP Bölge:2 %reg

  %ms %1 5IP Şehir:2 %cit

  %ms %1 5IP Enlem:2 %lat

  %ms %1 5IP Boylam:2 %lon

  %ms %1 5Organizasyon:2 %org

  %ms %1 5Servis Sağlayıcı:2 %isp

  %ms -5IP Bilgileri Sonu.. -

}



alias rp { return $replace($1-, IP Country:, IP Ülke:, IP Country Code:, IP Ülke Kodu:, IP Continent:, IP Kıta:, IP Region:, IP Bölge:, $&

  IP City:, IP Şehir:, IP Latitude:, IP Enlem:, IP Longitude:, IP Boylam:, Organization:, Organizasyon:, ISP Provider:, Servis Sağlayıcı:) }



on *:input:#kanal: {

  if $regex($1-,/^[!.]nerden\40\S+$/Si) { haltdef | unset %kanal | .remove ip-.html

    if $sock(yerbul*) { echo 5 -atge Devam Eden İşlem Var, Tekrar Deneyin. | return } 

  if $regex($2,/^\d/) { nerden $+($2,$chr(7),msg #) } }

  elseif $regex($1-,/^[!.]knerden\40\S+$/Si) { set -e %kanal $chan

    if $sock(yerbul*) { echo 5 -atge Devam Eden İşlem Var, Tekrar Deneyin. | return }

  if $regex($2,/^\d/) { nerden $+($2,$chr(7),msg #) } }

}



on *:sockopen:yerbul*:{ 

  var %sw sockwrite -n $sockname | set -e %ms $gettok($sock($sockname).mark, 2, 7)

  if ($sockerr) { $gettok($sock($sockname).mark, 2, 7) Bağlantı Hatası | sockclose $sockname | return }

  %sw GET /ip-address-locator.php?lookup= $+ $gettok($sock($sockname).mark, 1, 7) HTTP/1.1

  %sw Accept: text/html, application/xhtml+xml, */*

  %sw Referer: http://www.ipaddresslocation.org/

  %sw Accept-Language: tr-TR

  %sw User-Agent: Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; Trident/5.0)

  %sw Host: www.ipaddresslocation.org

  %sw Connection: Keep-Alive

  %sw $crlf

}



on *:sockread:yerbul*:{

  var %yerbul 

  sockread %yerbul

  if (<i>IP Country:</i> <b>*</b> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %con $derle(%yerbul)) }

  if (<i>IP Country Code:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %cnc $derle(%yerbul)) }

  if (<i>IP Continent:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %cot $derle(%yerbul)) }

  if (<i>IP Region:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %reg $derle(%yerbul)) }

  if (<i>IP City: <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %cit $derle(%yerbul)) }

  if (<i>IP Latitude:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %lat $derle(%yerbul)) }

  if (<i>IP Longitude:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %lon $derle(%yerbul)) }

  if (<i>Organization:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %org $derle(%yerbul)) }

  if (<i>ISP Provider:</i> <b>*</b><br /> iswm %yerbul) { $iif(%kanal, %ms $rp($derle(%yerbul)), set -e %isp $derle(%yerbul)) }

}



on *:sockclose:yerbul*:{ 

  if (%kanal) { halt }

  else {

    set %ipd $gettok($sock($sockname).mark, 1, 7) 

    write ip-.html <body bgcolor="LightBlue"> <body background="map.jpg"> <h2><a style="color:red;"> %ipd </a> IP Adresi Sonuçları </h2> $&

      <ul> $&

      <li><b><a style="color:DarkBlue;">IP Ülke:</a> $+ %con $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Ülke Kodu:</a> $+ %cnc $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Kıta:</a> $+ %cot $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Bölge:</a> $+ %reg $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Şehir:</a> $+ %cit $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Enlem:</a> $+ %lat $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">IP Boylam:</a> $+ %lon $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">Organizasyon:</a> $+ %org $+ </b></li><br /> $&

      <li><b><a style="color:DarkBlue;">Servis Sağlayıcı:</a> $+ %isp $+ </b></li><br /> $&

      </ul> $&

      <form> $&

      <div> <div align="right"> $&

      <input type="button" value="Kapat" style="font-weight:bold" style="background-color: #FCDFFF" style="height: 25px; width: 100px" onClick="location.href='mirc:wclose'"> $&   

      <input type="button" value="Kanala Yansıt" style="font-weight:bold" style="background-color: #FCDFFF" align="right" style="height: 25px; width: 120px" onClick="location.href='mirc:dyansit'"> $& 

      </form> $&

      </div>

  }

  .timerweb 1 2 webb 

}